C***************************************************************
C     Test program for subroutine LEBEM3 by Stephen Kirkup           
C***************************************************************
C
C  Version 2 (Version 1 2001). Revised test problems. Changes
C   in LIBEM3.
C  School Engineering, University of Central Lancashire 
C  www.uclan.ac.uk 
C  smkirkup@uclan.ac.uk
C  http://www.researchgate.net/profile/Stephen_Kirkup
C
C  This open source code can be found at
C   www.boundary-element-method.com/fortran/LEBEM3_T.FOR 
C
C  Issued under the GNU General Public License 2007, see gpl.txt
C
C  Part of the the author's open source BEM packages. 
C  All codes and manuals can be downloaded from 
C  www.boundary-element-method.com
C
C
C***************************************************************
C This program is a test for the subroutine LEBEM3. The program computes
C  the solution to a Laplace problem exterior to a sphere by the 
C  boundary element method.
C
C Background
C ----------
C
C We wish to solve the Laplace equation
C
C                  __ 2              
C                  \/    {\phi}   =  0  
C
C
C For the exterior problem, the domain lies exterior to a closed 
C  boundary S. The boundary condition may be Dirichlet, Robin or 
C  Neumann. It is assumed to have the following general form
C
C            {\alpha}(q) {\phi}(q) + {\beta}(q) v(q) = f(q)
C    
C  where {\phi}(q) is the velocity potential at the point q on S, v(q) 
C  is the derivative of {\phi} with respect to the outward normal to S 
C  at q and {\alpha}, {\beta} and f are real-valued functions defined
C   on S. 
C
C Subroutine LEBEM3 accepts a description of the boundary of the domain 
C  and the position of the exterior points where the solution ({\phi}) 
C  is sought, the boundary condition and returns the solution ({\phi} 
C  and v) on S and the value of {\phi} at the exterior points.
C

C The test problems
C -----------------
C
C In this test the domain is a sphere of radius 1 (metre). The solution
C  to the problem with a Dirichlet boundary condition ({\alpha}=1, 
C  {\beta}=0) on the upper surface (z>=0) and with a Neumann boundary 
C  condition  ({\alpha}=0, beta=1) on the lower surface (z<0) are 
C  sought. 
C Assuming the sphere is centred at the origin the boundary conditions
C  are specified through taking the solution to be determined by
C
C                                       
C                      {\phi} =  1/r ,
C
C  where r is the distance from a point within the sphere,
C  which is a solution of the Laplace equation.
C
C The boundary is described by a set of NS=36 planar triangular elements
C  of approximately equal size. The boundary solution points are the 
C  centres of the elements. 
C The solution is sought at the exterior points (0,2), (10,10).

C----------------------------------------------------------------------

C The PARAMETER statement
C -----------------------
C There are four components in the PARAMETER statement.
C integer MAXNS   : The limit on the number of boundary elements.
C integer MAXNV   : The limit on the number of vertices.
C integer MAXNPE  : The limit on the number of exterior points.


C External modules related to the package
C ---------------------------------------
C subroutine LEBEM3: Subroutine for solving the exterior Laplace
C  equation (file LEBEM3.FOR contains the subroutine LEBEM3)
C subroutine H3LC: Returns the individual discrete Laplace integral
C  operators. (file H3LC.FOR contains H3LC and subordinate routines)
C subroutine GLS: Solves a general linear system of equations.
C  (file GLS.FOR contains CGSL and subordinate routines)
C file GEOM3D.FOR contains the set of relevant geometric subroutines


C The program 

      PROGRAM LEBEM3T
      IMPLICIT NONE

C VARIABLE DECLARATION
C --------------------

C  PARAMETERs for storing the limits on the dimension of arrays
C   Limit on the number of elements
      INTEGER    MAXNS
      PARAMETER (MAXNS=40)
C   Limit on the number of vertices (equal to the number of elements)
      INTEGER    MAXNV
      PARAMETER (MAXNV=30)
C   Limit on the number of points exterior to the boundary, where 
C    the solutions are sought
      INTEGER    MAXNPE
      PARAMETER (MAXNPE=6)

C  Constants
C   Real scalars: 0, 1, 2, pi
      REAL*8 ZERO,ONE,THREE

C  Geometrical description of the boundary(ies)
C   Number of elements and counter
      INTEGER    NS,IS
C   Number of collocation points (on S) and counter
      INTEGER    NSP,ISP
C   Number of vetices and counter
      INTEGER    NV,IV
C   Index of nodal coordinate for defining boundaries (standard unit is 
C    metres)
      REAL*8     VERTEX(MAXNV,3)
C   The three nodes that define each element on the boundaries
      INTEGER    SELV(MAXNS,3)
C   The points exterior to the boundary(ies) where the solutions 
C    are sought and the directional vectors at those points.
C    [Only necessary if an exterior solution is sought.]
C    Number of exterior points and counter
      INTEGER    NPE,IPE
C    Coordinates of the exterior points
      REAL*8     PEXT(MAXNPE,3)


C   Data structures that are used to define each test problem in turn
C    and are input parameters to LEBEM3.
C    SALPHA(j) is assigned the value of {\alpha} at the centre of the 
C     j-th element.
      REAL*8 SALPHA(MAXNS)
C    SBETA(j) is assigned the value of {\beta} at the centre of the 
C     j-th element.
      REAL*8 SBETA(MAXNS)
C    SF(j) is assigned the value of f at the centre of the j-th element.
      REAL*8 SF(MAXNS)

C   Incident field
C    real SIPHI(MAXNSE): The incident velocity potential at the
C     centres of the elements
      REAL*8 SIPHI(MAXNS)
C    real PIIPHI(MAXNPE): The incident velocity potential at the chosen
C    interior points
      REAL*8 PIIPHI(MAXNPE)

C  Validation and control parameters for LEBEM3
C   Switch for particular solution
      LOGICAL    LSOL
C   Validation switch
      LOGICAL    LVALID
C   The maximum absolute error in the parameters that describe the
C    geometry of the boundary.
      REAL*8     EGEOM

C Output from subroutine LEBEM3
C  The velocity potential (phi - the solution) at the centres of the 
C   elements
      REAL*8     SPHI(MAXNS)
C  The normal derivative of the velocity potential at the centres of the
C    elements
      REAL*8     SVEL(MAXNS)
C  The velocity potential (phi - the solution) at exterior points
      REAL*8     PEIPHI(MAXNPE)

C Workspace for LEBEM3
      REAL*8 L_SS(MAXNS,MAXNS)
      REAL*8 M_SSMINUS(MAXNS,MAXNS)
      REAL*8 L_DS(MAXNPE,MAXNS)
      REAL*8 M_DS(MAXNPE,MAXNS)
      REAL*8 WKSPC1(MAXNS)
      REAL*8 WKSPC2(MAXNS)
      REAL*8 WKSPC3(MAXNS)
      REAL*8 C(MAXNS)
      INTEGER*4 PERM(MAXNS)
      LOGICAL XORY(MAXNS)

      REAL*8 P(3),PHI

C  Counter through the x,y coordinates
      INTEGER    ICOORD

C  The coordinates of the centres of the elements  
      REAL*8     SELCNT(MAXNS,3)

 

C INITIALISATION
C --------------

C Set constants
      ZERO=0.0D0
      ONE=1.0D0
      THREE=3.0D0
 



C Describe the nodes and elements that make up the boundary
C  :The unit sphere, centred at the origin is divided 
C  : into NS=36 uniform elements. VERTEX and SELV are defined 
C  : anti-clockwise around the boundary so that the normal to the 
C  : boundary is assumed to be outward
C  :Set up nodes
C  : Set NS, the number of elements
      NS=36
C  : Set NV, the number of vertices (equal to the number of elements)
      NV=NS
C  : Set coordinates of the nodes


C   Set up VERTEX, the coordinates of the vertices of the elements
      NV=20
      DATA ((VERTEX(IV,ICOORD),ICOORD=1,3),IV=1,20)
     * / 0.000D0, 0.000D0, 1.000D0,
     *   0.000D0, 0.745D0, 0.667D0,
     *   0.645D0, 0.372D0, 0.667D0,
     *   0.645D0,-0.372D0, 0.667D0,
     *   0.000D0,-0.745D0, 0.667D0,
     *  -0.645D0,-0.372D0, 0.667D0,
     *  -0.645D0, 0.372D0, 0.667D0,
     *   0.500D0, 0.866D0, 0.000D0,
     *   1.000D0, 0.000D0, 0.000D0,
     *   0.500D0,-0.866D0, 0.000D0,
     *  -0.500D0,-0.866D0, 0.000D0,
     *  -1.000D0, 0.000D0, 0.000D0,
     *  -0.500D0, 0.866D0, 0.000D0,
     *   0.000D0, 0.745D0,-0.667D0,
     *   0.645D0, 0.372D0,-0.667D0,
     *   0.645D0,-0.372D0,-0.667D0,
     *   0.000D0,-0.745D0,-0.667D0,
     *  -0.645D0,-0.372D0,-0.667D0,
     *  -0.645D0, 0.372D0,-0.667D0,
     *   0.000D0, 0.000D0,-1.000D0/


C  : Set nodal indices that describe the elements of the boundarys.
C  :  The indices refer to the nodes in VERTEX. The order of the
C  :  nodes in SELV dictates that the normal is outward from the 
C  :  boundary into the domain.
      DATA ((SELV(IS,ICOORD),ICOORD=1,3),IS=1,36)
     * / 1, 3, 2,    1, 4, 3,    1, 5, 4,    1, 6, 5,
     *   1, 7, 6,    1, 2, 7,    2, 3, 8,    3, 9, 8,
     *   3, 4, 9,    4,10, 9,    4, 5,10,    5,11,10,
     *   5, 6,11,    6,12,11,    6, 7,12,    7,13,12,
     *   7, 2,13,    2, 8,13,    8,15,14,    8, 9,15,
     *   9,16,15,    9,10,16,   10,17,16,   10,11,17,
     *  11,18,17,   11,12,18,   12,19,18,   12,13,19,
     *  13,14,19,   13, 8,14,   14,15,20,   15,16,20,
     *  16,17,20,   17,18,20,   18,19,20,   19,14,20/


C Set the centres of the elements, the collocation points
      DO IS=1,NS
        SELCNT(IS,1)=(VERTEX(SELV(IS,1),1)
     *   +VERTEX(SELV(IS,2),1)+VERTEX(SELV(IS,3),1))/THREE
        SELCNT(IS,2)=(VERTEX(SELV(IS,1),2)
     *   +VERTEX(SELV(IS,2),2)+VERTEX(SELV(IS,3),2))/THREE
        SELCNT(IS,3)=(VERTEX(SELV(IS,1),3)
     *   +VERTEX(SELV(IS,2),3)+VERTEX(SELV(IS,3),3))/THREE
      END DO



C Set the points in the domain where the solutions are sought, PEXT. 
C : Let them be the points (0,0,2), (10,10,10).
      NPE=2
      DATA ((PEXT(IPE,ICOORD),ICOORD=1,3),IPE=1,2)
     *  /  0.000D0,     0.000D0,  4.000D0,
     *    10.000D0,    10.000D0, 10.000D0 /


C The number of points on the boundary is equal to the number of 
C  elements
      NSP=NS
        

C  :Switch for particular solution
      LSOL=.TRUE.
C  :Switch on the validation of LEBEM3
      LVALID=.TRUE.
C  :Set EGEOM
      EGEOM=1.0D-6


C   Set up particular alpha and beta functions 
      DO 640 ISP=1,NSP
        P(1)=SELCNT(ISP,1)
        P(2)=SELCNT(ISP,2)
        P(3)=SELCNT(ISP,3)
        SALPHA(ISP)=ONE
        SBETA(ISP)=ZERO
        SF(ISP)=PHI(P)
640     CONTINUE
        DO 660 ISP=1,NSP
          SIPHI(ISP)=ZERO
660     CONTINUE
        DO 670 IPE=1,NPE
          PIIPHI(IPE)=ZERO
670     CONTINUE

       
        CALL LEBEM3(MAXNV,NV,VERTEX,MAXNS,NS,SELV,
     *             MAXNPE,NPE,PEXT,
     *             SALPHA,SBETA,SF,SIPHI,PIIPHI,
     *             LSOL,LVALID,EGEOM,
     *             SPHI,SVEL,PEIPHI,
     *             L_SS,M_SSMINUS,L_DS,M_DS,
     *             PERM,XORY,C,WKSPC1,WKSPC2,WKSPC3)


C  Open file for the output data
      OPEN(UNIT=20,FILE='LEBEM3.OUT')
      WRITE(20,*) 'Solutions at the exterior points'
      WRITE(20,*) '   P(1)      P(2)      P(3)     Computed    Exact'
      DO 800 IPE=1,NPE
        P(1)=PEXT(IPE,1)
        P(2)=PEXT(IPE,2)
        P(3)=PEXT(IPE,3)
        WRITE(20,999) P(1),P(2),P(3),PEIPHI(IPE),PHI(P)
800   CONTINUE


999   FORMAT(5F10.4)
      CLOSE(20)

      END

      REAL*8 FUNCTION PHI(P)
      REAL*8 P(3)
      REAL*8 SIZE3
      PHI=1/SIZE3(P)
      END




                                   
